source: azure_iot_hub_f767zi/trunk/asp_baseplatform/target/stm32f767nucleo144_gcc/stm32f7xx_ram.ld@ 457

MEMORY
{
    ROM (rx) : ORIGIN = 0x08000000, LENGTH = 2048K
    RAM (rwx) : ORIGIN = 0x20000000, LENGTH = 512K
}

OUTPUT_FORMAT("elf32-littlearm", "elf32-bigarm","elf32-littlearm") 
OUTPUT_ARCH(arm)

PROVIDE(hardware_init_hook = 0);
PROVIDE(software_init_hook = 0);
PROVIDE(software_term_hook = 0);
STARTUP(start.o)
ENTRY(_kernel__start)

SECTIONS
{
    .text :
    {  
        __text = . ; 
        KEEP(*(.vector))
            . = ALIGN(16);
        *(.text*)
        *(.glue_7t)
        *(.glue_7)
    } > RAM
    _etext = .  ;
    PROVIDE (etext = .) ;

    .rodata : { 
        *(.rodata*) 
    } > RAM

    . = ALIGN(4);
    .data   :  AT(__idata_start) 
    {
        __data_start = . ;
        *(vtable)
        *(.data*)
    } > RAM
    __idata_start = __data_start ;
    __idata_end = __idata_start + SIZEOF(.data);
    _edata  =  . ;
    PROVIDE (edata = .);
    . = ALIGN(4);

    .bss       :
    {
       __bss_start = .  ;
      *(.bss*)
      *(COMMON)
      . = ALIGN(32 / 8);
    } > RAM
   . = ALIGN(32 / 8);
     _end = .           ;
    __bss_end = .;
    PROVIDE (end = .)   ;

    .comment 0 : { *(.comment) }

  /* DWARF debug sections.
     Symbols in the DWARF debugging sections are relative to 
     the beginning of the section so we begin them at 0.  */

  /* DWARF 1 */
  .debug          0 : { *(.debug) }
  .line           0 : { *(.line) }

  /* GNU DWARF 1 extensions */
  .debug_srcinfo  0 : { *(.debug_srcinfo) }
  .debug_sfnames  0 : { *(.debug_sfnames) }

  /* DWARF 1.1 and DWARF 2 */
  .debug_aranges  0 : { *(.debug_aranges) }
  .debug_pubnames 0 : { *(.debug_pubnames) }

  /* DWARF 2 */
  .debug_info     0 : { *(.debug_info) }
  .debug_abbrev   0 : { *(.debug_abbrev) }
  .debug_line     0 : { *(.debug_line) }
  .debug_frame    0 : { *(.debug_frame) }
  .debug_str      0 : { *(.debug_str) }
  .debug_loc      0 : { *(.debug_loc) }
  .debug_macinfo  0 : { *(.debug_macinfo) }

  /* SGI/MIPS DWARF 2 extensions */
  .debug_weaknames 0 : { *(.debug_weaknames) }
  .debug_funcnames 0 : { *(.debug_funcnames) }
  .debug_typenames 0 : { *(.debug_typenames) }
  .debug_varnames  0 : { *(.debug_varnames) }
}