source: asp3_tinet_ecnl_rx/trunk/asp3_dcre/target/gr_sakura_gcc/gr_sakura.ld@ 364

Last change on this file since 364 was 364, checked in by coas-nagasima, 5 years ago

TINETとSocket APIなどを更新
File size: 2.2 KB
Line 
1MEMORY
2{
3 RAM : ORIGIN = 0x0, LENGTH = 131072
4 ROM : ORIGIN = 0xFFF00000, LENGTH = 1048576
5}
6
7SECTIONS
8{
9 .fvectors 0xFFFFFF80 : AT (0xFFFFFF80)
10 {
11 KEEP(*(.fvectors))
12 } > ROM
13 .text 0xFFF00000 : AT (0xFFF00000)
14 {
15 *(.text)
16 *(.text.*)
17 *(P)
18 etext = .;
19 } > ROM
20 .rvectors :
21 {
22 _rvectors_start = .;
23 KEEP(*(.rvectors))
24 _rvectors_end = .;
25 } > ROM
26 .init :
27 {
28 *(.init)
29 __preinit_array_start = .;
30 *(.preinit_array)
31 __preinit_array_end = .;
32 __init_array_start = (. + 3) & ~ 3;
33 *(.init_array)
34 *(SORT(.init_array.*))
35 __init_array_end = .;
36 __fini_array_start = .;
37 *(.fini_array)
38 *(SORT(.fini_array.*))
39 __fini_array_end = .;
40 } > ROM
41 .fini :
42 {
43 *(.fini)
44 } > ROM
45 .got :
46 {
47 *(.got)
48 *(.got.plt)
49 } > ROM
50 .rodata :
51 {
52 _brodata = .;
53 *(.rodata)
54 *(.rodata.*)
55 *(C_1)
56 *(C_2)
57 *(C)
58 _mrb_preset_const_start = .;
59 *(.mrb_preset_const)
60 _mrb_preset_const_end = .;
61 _erodata = .;
62 } > ROM
63 .eh_frame_hdr :
64 {
65 *(.eh_frame_hdr)
66 } > ROM
67 .eh_frame :
68 {
69 *(.eh_frame)
70 } > ROM
71 .jcr :
72 {
73 *(.jcr)
74 } > ROM
75 .tors :
76 {
77 __CTOR_LIST__ = .;
78 . = ALIGN(2);
79 ___ctors = .;
80 *(.ctors)
81 ___ctors_end = .;
82 __CTOR_END__ = .;
83 __DTOR_LIST__ = .;
84 ___dtors = .;
85 *(.dtors)
86 ___dtors_end = .;
87 __DTOR_END__ = .;
88 . = ALIGN(2);
89 _mdata = .;
90 } > ROM
91 .istack 0x00000 (NOLOAD) : AT (0x00000)
92 {
93 *(SI)
94 _istack = .;
95 } > RAM
96 .ustack 0x00400 (NOLOAD) : AT (0x00400)
97 {
98 _heap_stop = .;
99 *(SU)
100 _ustack = .;
101 } > RAM
102 .gcc_exc :
103 {
104 *(.gcc_exc)
105 } > RAM
106 .data : AT (_mdata)
107 {
108 _data = .;
109 *(.data)
110 *(.data.*)
111 . = ALIGN(4);
112 *(D)
113 *(D_1)
114 . = ALIGN(2);
115 *(D_2)
116 _mrb_preset_data_start = .;
117 *(.mrb_preset_data)
118 _mrb_preset_data_end = .;
119 _edata = .;
120 } > RAM
121 .bss :
122 {
123 _bss = .;
124 *(.bss)
125 *(.bss.**)
126 *(COMMON)
127 . = ALIGN(4);
128 *(B)
129 *(B_1)
130 . = ALIGN(2);
131 *(B_2)
132 _ebss = .;
133 . = ALIGN(4);
134 _end = .;
135 } > RAM
136 .eth_memory (NOLOAD) :
137 {
138 . = ALIGN(32);
139 KEEP(*(ETH_MEMORY))
140 } > RAM
141 .heap (NOLOAD) :
142 {
143 *(.heap*)
144 __HeapBase = .;
145 } > RAM
146 __HeapLimit = ORIGIN(RAM) + LENGTH(RAM);
147}
Note: See TracBrowser for help on using the repository browser.