/*
 *  TOPPERS/SSP Kernel
 *      Smallest Set Profile Kernel
 *
 *  Copyright (C) 2018 by Naoki Saito
 *             Nagoya Municipal Industrial Research Institute, JAPAN
 *
 *  上記著作権者は，以下の(1)〜(4)の条件を満たす場合に限り，本ソフトウェ
 *  ア（本ソフトウェアを改変したものを含む．以下同じ）を使用・複製・改
 *  変・再配布（以下，利用と呼ぶ）することを無償で許諾する．
 *  (1) 本ソフトウェアをソースコードの形で利用する場合には，上記の著作
 *      権表示，この利用条件および下記の無保証規定が，そのままの形でソー
 *      スコード中に含まれていること．
 *  (2) 本ソフトウェアを，ライブラリ形式など，他のソフトウェア開発に使
 *      用できる形で再配布する場合には，再配布に伴うドキュメント（利用
 *      者マニュアルなど）に，上記の著作権表示，この利用条件および下記
 *      の無保証規定を掲載すること．
 *  (3) 本ソフトウェアを，機器に組み込むなど，他のソフトウェア開発に使
 *      用できない形で再配布する場合には，次のいずれかの条件を満たすこ
 *      と．
 *    (a) 再配布に伴うドキュメント（利用者マニュアルなど）に，上記の著
 *        作権表示，この利用条件および下記の無保証規定を掲載すること．
 *    (b) 再配布の形態を，別に定める方法によって，TOPPERSプロジェクトに
 *        報告すること．
 *  (4) 本ソフトウェアの利用により直接的または間接的に生じるいかなる損
 *      害からも，上記著作権者およびTOPPERSプロジェクトを免責すること．
 *      また，本ソフトウェアのユーザまたはエンドユーザからのいかなる理
 *      由に基づく請求からも，上記著作権者およびTOPPERSプロジェクトを
 *      免責すること．
 *
 *  本ソフトウェアは，無保証で提供されているものである．上記著作権者お
 *  よびTOPPERSプロジェクトは，本ソフトウェアに関して，特定の使用目的
 *  に対する適合性も含めて，いかなる保証も行わない．また，本ソフトウェ
 *  アの利用により直接的または間接的に生じたいかなる損害に関しても，そ
 *  の責任を負わない．
 *
 */

/*
 *  プロセッサ依存モジュール アセンブリ言語部（GIC）
 */

#define TOPPERS_MACRO_ONLY
#define UINT_C(val)	(val)		/* uint_t型の定数を作るマクロ */
#define ULONG_C(val)	(val)		/* ulong_t型の定数を作るマクロ */
#define CAST(type, val)	(val)		/* 型キャストを行うマクロ */

#define GIC_REG(base, offset)   ((base) + (offset))

#include "kernel_impl.h"

/*
 *  例外入口のGIC操作
 *    x22: 例外番号(0..7)
 */
    .text
    .align 2
    .global gic_exc_entry
gic_exc_entry:
    mov    x0, sp             // 割込み優先度マスクの保存
    ldr    x9, =GICC_PMR
    ldr    x9, [x9]
    str    x9, [x0, #0]

    str    x22, [x0, #8]      // 例外番号の保存

    mov    x1, x22            // 引数をセットして call_exc_handler 呼び出し
    ldr    x30, =gic_ret_int
    b      call_exc_handler

/*
 *  割込み入口のGIC操作
 */
    .text
    .align 2
    .global gic_int_entry
gic_int_entry:
    mov    x0,    sp
    /*
     * 割込みコントローラ操作
     */
    ldr    x9, =GICC_IAR      //  割込み要因を保存
    ldr    w9, [x9]
    str    w9, [x0, #8]

    ldr    x10, =GICC_RPR     //  割込み要因の優先度を割込み優先度マスクにセット
    ldr    w10, [x10]

    ldr    x11, =GICC_PMR
    ldr    w12, [x11]         //  割込み発生前のマスクの値を取り出しておく
    str    w10, [x11]

    dsb    sy                 // 割込み優先度マスクがセットされるのを待つ

    str    w12, [x0, #0]      //  割込み発生前の優先度マスクを保存
    ldr    x11, =GICC_EOIR    //  EOIの発行
    str    w9, [x11]

    mov    w0, w9             // 引数をセットして call_int_handler 呼び出し
    ldr    x30, =gic_ret_int
    b     call_int_handler


/*
 *  割込み出口のGIC操作
 */
    .text
    .align 2
gic_ret_int:
    mov    x0, sp
    ldr    w9, [x0, #0]       // 割込み優先度マスクを元に戻す
    ldr    x10, =GICC_PMR
    str    w9, [x10]

    dsb    sy                 // 割込み優先度マスクがセットされるのを待つ

    b      ret_int