/*
 *  TOPPERS/SSP Kernel
 *      Smallest Set Profile Kernel
 * 
 *  Copyright (C) 2000-2003 by Embedded and Real-Time Systems Laboratory
 *                              Toyohashi Univ. of Technology, JAPAN
 *  Copyright (C) 2007 by Embedded and Real-Time Systems Laboratory
 *              Graduate School of Information Science, Nagoya Univ., JAPAN
 *  Copyright (C) 2012 by Meika Sugimoto
 *  Copyright (C) 2013-2015 by Naoki Saito
 *             Nagoya Municipal Industrial Research Institute, JAPAN
 * 
 *  上記著作権者は，以下の(1)〜(4)の条件を満たす場合に限り，本ソフトウェ
 *  ア（本ソフトウェアを改変したものを含む．以下同じ）を使用・複製・改
 *  変・再配布（以下，利用と呼ぶ）することを無償で許諾する．
 *  (1) 本ソフトウェアをソースコードの形で利用する場合には，上記の著作
 *      権表示，この利用条件および下記の無保証規定が，そのままの形でソー
 *      スコード中に含まれていること．
 *  (2) 本ソフトウェアを，ライブラリ形式など，他のソフトウェア開発に使
 *      用できる形で再配布する場合には，再配布に伴うドキュメント（利用
 *      者マニュアルなど）に，上記の著作権表示，この利用条件および下記
 *      の無保証規定を掲載すること．
 *  (3) 本ソフトウェアを，機器に組み込むなど，他のソフトウェア開発に使
 *      用できない形で再配布する場合には，次のいずれかの条件を満たすこ
 *      と．
 *    (a) 再配布に伴うドキュメント（利用者マニュアルなど）に，上記の著
 *        作権表示，この利用条件および下記の無保証規定を掲載すること．
 *    (b) 再配布の形態を，別に定める方法によって，TOPPERSプロジェクトに
 *        報告すること．
 *  (4) 本ソフトウェアの利用により直接的または間接的に生じるいかなる損
 *      害からも，上記著作権者およびTOPPERSプロジェクトを免責すること．
 *      また，本ソフトウェアのユーザまたはエンドユーザからのいかなる理
 *      由に基づく請求からも，上記著作権者およびTOPPERSプロジェクトを
 *      免責すること．
 * 
 *  本ソフトウェアは，無保証で提供されているものである．上記著作権者お
 *  よびTOPPERSプロジェクトは，本ソフトウェアに関して，特定の使用目的
 *  に対する適合性も含めて，いかなる保証も行わない．また，本ソフトウェ
 *  アの利用により直接的または間接的に生じたいかなる損害に関しても，そ
 *  の責任を負わない．
 * 
 */

/*
 * ターゲット依存部　アセンブリ言語（LPCXPRESSO-LPC812用）
 */

#define TOPPERS_MACRO_ONLY
#define UINT_C(val)			(val)
#define ULONG_C(val)		(val)
#include "kernel_impl.h"
#include "lpcxpresso_lpc812.h"

/*
 * 低レベルのターゲット依存の初期化
 *
 * メモリ初期化の前に呼び出される
 */
	.globl	hardware_init_hook

	.text
	.align 2
	.syntax unified
	.code 16
	.thumb
	.type hardware_init_hook, function
hardware_init_hook:
	// SWM, IOCON のクロックON
	ldr 	r3, .L6+4	// TADR_SYSAHBCLKCTRL
	ldr 	r1, .L6+8	// TVALUE_SYSAHBCLKCTRL
	ldr 	r2, [r3]
	orrs	r2, r2, r1
	str 	r2, [r3]

#ifdef USE_SYSTEM_PLL
#ifdef USE_EXTERNAL_OSCILLATOR
	// PIO0_8, PIO0_9 を非活性に
	ldr 	r3, .L6+16	// TADR_IOCON_BASE

	movs 	r1, #TBITPTN_IOCON_PIOx_MODE
	mvns	r1, r1
	ldr 	r2, [r3, #TOFFSET_IOCON_PIO0_8]
	ands	r2, r2, r1
	str 	r2, [r3, #TOFFSET_IOCON_PIO0_8]

	ldr 	r2, [r3, #TOFFSET_IOCON_PIO0_9]
	ands	r2, r2, r1
	str 	r2, [r3, #TOFFSET_IOCON_PIO0_9]

	// XTALIN, XTALOUT 端子を有効に
	ldr 	r3, .L6+20	// TADR_PINENABLE0
	movs 	r1, #(TBITPTN_SWM_PINENABLE0_XTALINEN | TBITPTN_SWM_PINENABLE0_XTALOUTEN)
	mvns	r1, r1
	ldr 	r2, [r3]
	ands	r2, r2, r1
	str 	r2, [r3]

	// 水晶発信器 power on
	ldr 	r3, .L6+12	// TADR_PDRUNCFG
	movs 	r1, #TBITPTN_SYSCON_PDRUNCFG_SYSOSCPD
	mvns	r1, r1
	ldr 	r2, [r3]
	ands	r2, r2, r1
	str 	r2, [r3]

	// システムオシレータの設定
	ldr 	r3, .L6	// TADR_SYSCON_BASE
	movs	r2, #TVALUE_SYSCON_SYSOSCCTRL
	str 	r2, [r3, #TOFFSET_SYSCON_SYSOSCCTRL]

	// ちょっと待つ
	movs	r1, #0
.L1:
	str     r1, [sp, #4]
	cmp     r1, #199
	bhi     .L2
	nop
	adds     r1, #1
	b       .L1
#endif /* USE_EXTERNAL_OSCILLATOR */

.L2:
	// System PLL クロックの選択 (XTALまたはIRCオシレータ)
	ldr 	r3, .L6	// TADR_SYSCON_BASE
	movs	r2, #TVALUE_SYSCON_SYSPLLCLKSEL
	str 	r2, [r3, #TOFFSET_SYSCON_SYSPLLCLKSEL]

	// クロックソースの更新
	movs	r2, #TBITPTN_SYSCON_SYSPLLCLKUEN_ENA
	str 	r2, [r3, #TOFFSET_SYSCON_SYSPLLCLKUEN]

	// 更新されるまで待つ
.L3:
	ldr 	r1, [r3, #TOFFSET_SYSCON_SYSPLLCLKUEN]
	ands	r1, r2  	// r1 <-- r1(=SYSPLLCLKUEN) & r2(=TBITPTN_SYSPLLCLKUEN_ENA)
	beq 	.L3     	// if(r1 == 0) goto .L3

	// PLLの逓倍率の設定
	movs	r2, #TVALUE_SYSCON_SYSPLLCTRL
	str 	r2, [r3, #TOFFSET_SYSCON_SYSPLLCTRL]

	// System PLL 電源ON
	ldr 	r3, .L6+12	// TADR_PDRUNCFG
	movs 	r1, #TBITPTN_SYSCON_PDRUNCFG_SYSPLLPD
	mvns	r1, r1
	ldr 	r2, [r3]
	ands	r2, r2, r1
	str 	r2, [r3]

	// PLLロック待ち
	ldr 	r3, .L6	// TADR_SYSCON_BASE
	movs	r2, #TBITPTN_SYSCON_SYSPLLSTAT_LOCK
.L4:
	ldr 	r1, [r3, #TOFFSET_SYSCON_SYSPLLSTAT]
	ands	r1, r2  	// r1 <-- r1(=SYSPLLSTAT) & r2(=TBITPTN_SYSPLLSTAT_LOCK)
	beq 	.L4         // if(r1 == 0) goto .L4
#endif /* USE_SYSTEM_PLL */

	// メインクロック出力の選択
	ldr 	r3, .L6	// TADR_SYSCON_BASE
	movs	r2, #TVALUE_SYSCON_MAINCLKSEL
	str 	r2, [r3, #TOFFSET_SYSCON_MAINCLKSEL]

	// メインクロックソースの更新
	movs	r2, #TBITPTN_SYSCON_MAINCLKUEN_ENA
	str 	r2, [r3, #TOFFSET_SYSCON_MAINCLKUEN]

	// 更新されるまで待つ
.L5:
	ldr 	r1, [r3, #TOFFSET_SYSCON_MAINCLKUEN]
	ands	r1, r2	// r1 <-- r1(=MAINCLKUEN) & r2(=TBITPTN_MAINCLKUEN_ENA)
	beq 	.L5   	// if(r1 == 0) goto .L5

	// システムクロックの分周比設定
	movs	r2, #TVALUE_SYSCON_SYSAHBCLKDIV
	str 	r2, [r3, #TOFFSET_SYSCON_SYSAHBCLKDIV]

	// トレースクロックの設定(必要なら．Not Yet)

	bx	lr

	.align 2
.L6:
	.word	TADR_SYSCON_BASE
	.word	TADR_SYSCON_SYSAHBCLKCTRL
	.word	TVALUE_SYSCON_SYSAHBCLKCTRL
	.word	TADR_SYSCON_PDRUNCFG
	.word	TADR_IOCON_BASE
	.word	TADR_SWM_PINENABLE0