/*
 *  TOPPERS/OSEK Kernel
 *      Toyohashi Open Platform for Embedded Real-Time Systems/
 *      OSEK Kernel
 * 
 *  Copyright (C) 2000-2003 by Embedded and Real-Time Systems Laboratory
 *                              Toyohashi Univ. of Technology, JAPAN
 *  Copyright (C) 2004 by Embedded and Real-Time Systems Laboratory
 *              Graduate School of Information Science, Nagoya Univ., JAPAN
 *  Copyright (C) 2001-2003 by Industrial Technology Institute,
 *                              Miyagi Prefectural Government, JAPAN
 *  Copyright (C) 2006 by Witz Corporation, JAPAN
 * 
 *  上記著作権者は，以下の (1)〜(4) の条件か，Free Software Foundation 
 *  によって公表されている GNU General Public License の Version 2 に記
 *  述されている条件を満たす場合に限り，本ソフトウェア（本ソフトウェア
 *  を改変したものを含む．以下同じ）を使用・複製・改変・再配布（以下，
 *  利用と呼ぶ）することを無償で許諾する．
 *  (1) 本ソフトウェアをソースコードの形で利用する場合には，上記の著作
 *      権表示，この利用条件および下記の無保証規定が，そのままの形でソー
 *      スコード中に含まれていること．
 *  (2) 本ソフトウェアを，ライブラリ形式など，他のソフトウェア開発に使
 *      用できる形で再配布する場合には，再配布に伴うドキュメント（利用
 *      者マニュアルなど）に，上記の著作権表示，この利用条件および下記
 *      の無保証規定を掲載すること．
 *  (3) 本ソフトウェアを，機器に組み込むなど，他のソフトウェア開発に使
 *      用できない形で再配布する場合には，次のいずれかの条件を満たすこ
 *      と．
 *    (a) 再配布に伴うドキュメント（利用者マニュアルなど）に，上記の著
 *        作権表示，この利用条件および下記の無保証規定を掲載すること．
 *    (b) 再配布の形態を，別に定める方法によって，TOPPERSプロジェクトに
 *        報告すること．
 *  (4) 本ソフトウェアの利用により直接的または間接的に生じるいかなる損
 *      害からも，上記著作権者およびTOPPERSプロジェクトを免責すること．
 * 
 *  本ソフトウェアは，無保証で提供されているものである．上記著作権者お
 *  よびTOPPERSプロジェクトは，本ソフトウェアに関して，その適用可能性も
 *  含めて，いかなる保証も行わない．また，本ソフトウェアの利用により直
 *  接的または間接的に生じたいかなる損害に関しても，その責任を負わない．
 * 
 */

/*
 *  カーネル用のスタートアップモジュール(SH2用)
 */

#define _MACRO_ONLY
#include "cpu_config.h"
#include "sys_defs.h"

/*
 *  セクション定義のインクルード
 */

/*	外部参照宣言 */
	.globl	hardware_init_hook
	.globl	software_init_hook
	.globl	_main

	.section ".text" , "ax"
	.align	2
/*
 *  リセット後はここからプログラム開始
 */
	.globl _start
_start:
	/*
	 *  SR設定
	 */
	mov.l	maxipm , r0
	ldc 	r0 , sr
	
	/*
	 *  割込みスタックポインタ初期化
	 */
	mov.l	stack_init, r15
	
	/*
	 *  割り込みベクタ先頭番地設定
	 */
	mov.l	vbr_init, r0
	ldc	r0 , vbr
	
	/*
	 *  hardware_init_hook の呼出し（0 でない場合）
	 *
	 *  ターゲットハードウェアに依存して必要な初期化処理がある場合
	 *  は，hardware_init_hook という関数を用意する．
	 */
	mov.l	hardware_init_hook_adr , r1
	tst		r1 , r1
	bt		hardware_init_hook_r
	jsr		@r1
	nop
hardware_init_hook_r:

	/*
	 *  bss領域のゼロクリア
	 */
	mov.l	_bss_start_adr , r0
	mov.l	_bss_end_adr , r1
	mov		#0 , r2
bss_clear_loop:
	cmp/ge	r1 , r0
	bt		bss_clear_end
	mov.l	r2 , @r0
	add		#4 , r0
	bra		bss_clear_loop
bss_clear_end:
	/*
	 *  data領域の初期化
	 */
	mov.l   __idata_start_adr,r1
	mov.l   __idata_end_adr,r2
	cmp/eq  r1,r2
	bt      data_init_end
	mov.l   __data_start_adr,r0
data_init:
	mov.l   @r1+,r4
	mov.l   r4,@r0
	cmp/hi  r1,r2
	add     #4,r0
	bt      data_init
data_init_end:
	/*
	 *  software_init_hook を呼出し（0 でない場合）
	 *
	 *  ソフトウェア環境（特にライブラリ）に依存して必要な初期化処
	 *  理がある場合は，software_init_hook という関数を用意すれば
	 *  よい．
	 */
	mov.l	software_init_hook_adr , r1
	tst		r1 , r1
	bt		software_init_hook_r
	jsr		@r1
	nop
software_init_hook_r:
	/*
	 *  ユーザーメイン関数へジャンプ
	*/
	mov.l	main_adr , r0
	jsr	@r0
	nop
exit_loop:
	/*
	 *  mainから戻ってきた場合は安全のため無限ループ
	 */
	bra	exit_loop
	nop

stack_init:
	.long	STACK_TOP
vbr_init:
	.long	VECTOR_TOP
hardware_init_hook_adr:
	.long	_hardware_init_hook
software_init_hook_adr:
	.long	_software_init_hook
_bss_start_adr:
	.long	__bss_start
_bss_end_adr:
	.long	__bss_end
main_adr:
	.long	_main
maxipm:
	.long	0x000000f0
	
__idata_start_adr:
	.long 	__idata_start
__idata_end_adr:
	.long   __idata_end
__data_start_adr:
	.long  	__data_start

	.end