source: ssp_rpi3/trunk/target/rpi_arm64_gcc/rpi_arm64.ld@ 386

/*
 *  $Id:$
 */

OUTPUT_FORMAT("elf64-littleaarch64", "elf64-bigaarch64",
              "elf64-littleaarch64")
OUTPUT_ARCH(aarch64)

PROVIDE(hardware_init_hook = 0);
PROVIDE(software_init_hook = 0);
PROVIDE(software_term_hook = 0);

ENTRY(start)
SECTIONS
{
        . = 0x40000000;
        .text : {
                __start_text = .;
                 *(.text) 
                __end_kernel = .;
        }
        _etext = .;
        PROVIDE(etext = .);

        . = ALIGN(8);
        .rodata : {
                __start_rodata = .;
                *(.rodata)
                __end_rodata = .;
        }

        . = ALIGN(8);
        __start_idata = .;
        .data : AT(__start_idata){
                __start_data = .;
                 *(.data) 
                __end_data = .;
         }
        __end_idata = __start_idata + SIZEOF(.data);
        _edata = .;
        PROVIDE(edata = .);
        . = ALIGN(8);
        .bss : {
                __start_bss = .;
                *(.bss)
                *(COMMON)
                __end_bss = .;
         }
        . = ALIGN(8);
        _end = .;
        PROVIDE(end = .);
        . = . + 0x1000; /* 4kB of stack memory */
        stack_top = .;
        .comment 0 : { *(.comment) }    

        /*
         *  DWARF debug sections.
         *  Symbols in the DWARF debugging sections are relative to
         *  the beginning of the section so we begin them at 0.
         */

        /* DWARF 1 */
        .debug                  0 : { *(.debug) }
        .line                   0 : { *(.line) }

        /* GNU DWARF 1 extensions */
        .debug_srcinfo  0 : { *(.debug_srcinfo) }
        .debug_sfnames  0 : { *(.debug_sfnames) }

        /* DWARF 1.1 and DWARF 2 */
        .debug_aranges  0 : { *(.debug_aranges) }
        .debug_pubnames 0 : { *(.debug_pubnames) }

        /* DWARF 2 */
        .debug_info             0 : { *(.debug_info) }
        .debug_abbrev   0 : { *(.debug_abbrev) }
        .debug_line             0 : { *(.debug_line) }
        .debug_frame    0 : { *(.debug_frame) }
        .debug_str              0 : { *(.debug_str) }
        .debug_loc              0 : { *(.debug_loc) }
        .debug_macinfo  0 : { *(.debug_macinfo) }

        /* SGI/MIPS DWARF 2 extensions */
        .debug_weaknames 0 : { *(.debug_weaknames) }
        .debug_funcnames 0 : { *(.debug_funcnames) }
        .debug_typenames 0 : { *(.debug_typenames) }
        .debug_varnames  0 : { *(.debug_varnames) }

    /* Linker bugs ? */
    .note.gnu.build-id : {
        *(.note.gnu.build-id)
    }
}