source: EcnlProtoTool/trunk/asp3_dcre/arch/arm_gcc/common/gic_support.S@ 429

Last change on this file since 429 was 429, checked in by coas-nagasima, 4 years ago

ASP3, TINET, mbed を更新
  • Property svn:eol-style set to native
  • Property svn:mime-type set to text/plain;charset=UTF-8
File size: 6.8 KB
Line 
1/*
2 * TOPPERS Software
3 * Toyohashi Open Platform for Embedded Real-Time Systems
4 *
5 * Copyright (C) 2000-2003 by Embedded and Real-Time Systems Laboratory
6 * Toyohashi Univ. of Technology, JAPAN
7 * Copyright (C) 2006-2018 by Embedded and Real-Time Systems Laboratory
8 * Graduate School of Information Science, Nagoya Univ., JAPAN
9 *
10 * 上記著作権者は，以下の(1)～(4)の条件を満たす場合に限り，本ソフトウェ
11 * ア（本ソフトウェアを改変したものを含む．以下同じ）を使用・複製・改
12 * 変・再配布（以下，利用と呼ぶ）することを無償で許諾する．
13 * (1) 本ソフトウェアをソースコードの形で利用する場合には，上記の著作
14 * 権表示，この利用条件および下記の無保証規定が，そのままの形でソー
15 * スコード中に含まれていること．
16 * (2) 本ソフトウェアを，ライブラリ形式など，他のソフトウェア開発に使
17 * 用できる形で再配布する場合には，再配布に伴うドキュメント（利用
18 * 者マニュアルなど）に，上記の著作権表示，この利用条件および下記
19 * の無保証規定を掲載すること．
20 * (3) 本ソフトウェアを，機器に組み込むなど，他のソフトウェア開発に使
21 * 用できない形で再配布する場合には，次のいずれかの条件を満たすこ
22 * と．
23 * (a) 再配布に伴うドキュメント（利用者マニュアルなど）に，上記の著
24 * 作権表示，この利用条件および下記の無保証規定を掲載すること．
25 * (b) 再配布の形態を，別に定める方法によって，TOPPERSプロジェクトに
26 * 報告すること．
27 * (4) 本ソフトウェアの利用により直接的または間接的に生じるいかなる損
28 * 害からも，上記著作権者およびTOPPERSプロジェクトを免責すること．
29 * また，本ソフトウェアのユーザまたはエンドユーザからのいかなる理
30 * 由に基づく請求からも，上記著作権者およびTOPPERSプロジェクトを
31 * 免責すること．
32 *
33 * 本ソフトウェアは，無保証で提供されているものである．上記著作権者お
34 * よびTOPPERSプロジェクトは，本ソフトウェアに関して，特定の使用目的
35 * に対する適合性も含めて，いかなる保証も行わない．また，本ソフトウェ
36 * アの利用により直接的または間接的に生じたいかなる損害に関しても，そ
37 * の責任を負わない．
38 *
39 * $Id$
40 */
41
42/*
43 * カーネルの割込みコントローラ依存部のアセンブリ言語部（GIC用）
44 */
45
46#define TOPPERS_MACRO_ONLY
47#define TOPPERS_ASM_MACRO
48#define UINT_C(val) (val) /* uint_t型の定数を作るマクロ */
49#define ULONG_C(val) (val) /* ulong_t型の定数を作るマクロ */
50#define CAST(type, val) (val) /* 型キャストを行うマクロ */
51#define GIC_REG(base, offset) ((base) + (offset))
52#include "kernel_impl.h"
53#include "core_asm.inc"
54
55#if __TARGET_ARCH_ARM < 6
56#error gic_suport.S supports ARMv6 or later.
57#endif /* __TARGET_ARCH_ARM < 6 */
58
59/*
60 * 割込みハンドラ呼出し前の割込みコントローラ操作
61 *
62 * r4に割込み番号を返す．irc_end_intで用いる情報（割込み発生前の割込み
63 * 優先度マスク）を，スタックの先頭に保存する．
64 */
65 ATEXT
66 AALIGN(2)
67 AGLOBAL(irc_begin_int)
68ALABEL(irc_begin_int)
69 /*
70 * 割込み要因を取得する．
71 */
72#ifdef GIC_PL390_ERRATA /* GIC 390 Errata 801120への対策 */
73 ldr r1, =GICC_HPPIR
74 ldr r0, [r1]
75#endif /* GIC_PL390_ERRATA */
76 ldr r1, =GICC_IAR
77 ldr r3, [r1]
78 lsl r4, r3, #22 /* 下位10ビットを取り出す */
79 lsr r4, r4, #22
80
81#ifdef GIC_PL390_ERRATA /* GIC 390 Errata 733075への対策 */
82 movw r0, #1023
83 cmp r4, r0
84 beq irc_begin_int_errata_1
85 movw r0, #1022
86 cmp r4, r0
87 beq irc_begin_int_errata_1
88 cmp r3, #0
89 bne irc_begin_int_errata_2
90 ldr r1, =GICD_ISACTIVER(0) /* 割込み要求があるかチェック */
91 ldr r0, [r1]
92 tst r0, #0x01
93 movweq r4, #1024 /* 無効な割込みとみなす */
94ALABEL(irc_begin_int_errata_1)
95 ldr r1, =GICD_IPRIORITYR(0) /* 割込み優先度レジスタ0に書き込み */
96 ldr r0, [r1]
97 str r0, [r1]
98 asm_data_sync_barrier r0
99ALABEL(irc_begin_int_errata_2)
100#endif /* GIC_PL390_ERRATA */
101
102 /*
103 * 割込み要因の割込み優先度を求め，割込み優先度マスクに設定する．
104 */
105 ldr r1, =GICC_RPR /* 受け付けた割込みの割込み優先度を取得 */
106 ldr r0, [r1]
107 ldr r1, =GICC_PMR /* 割込み発生前の割込み優先度を取得 */
108 ldr r2, [r1]
109 str r0, [r1] /* 新しい割込み優先度マスクをセットする */
110 asm_data_sync_barrier r0 /* 割込み優先度マスクがセットされるのを待つ */
111 str r2, [sp] /* irc_end_intで用いる情報を保存 */
112
113 /*
114 * EOIを発行する．
115 */
116 ldr r1, =GICC_EOIR /* EOIレジスタへの書込み */
117 str r3, [r1]
118
119 /*
120 * r4に割込み番号を入れた状態でリターンする．
121 */
122 bx lr
123
124/*
125 * 割込みハンドラ呼出し後の割込みコントローラ操作
126 */
127 ATEXT
128 AALIGN(2)
129 AGLOBAL(irc_end_int)
130ALABEL(irc_end_int)
131 /*
132 * 割込み優先度マスクを元に戻す．
133 */
134 ldr r2, [sp] /* irc_begin_intで保存した情報を復帰 */
135 ldr r1, =GICC_PMR /* 割込み優先度マスクを元に戻す */
136 str r2, [r1]
137 bx lr
138
139/*
140 * CPU例外発生前の割込み優先度の取得
141 *
142 * CPU例外の発生で割込み優先度が変わることはないため，現在の割込み優先
143 * 度を返す．
144 */
145 ATEXT
146 AALIGN(2)
147 AGLOBAL(irc_get_intpri)
148ALABEL(irc_get_intpri)
149 /*
150 * 割込み優先度マスクを外部表現に変換して返す．
151 */
152 ldr r1, =GICC_PMR
153 ldr r0, [r1]
154 asr r0, r0, #GIC_PRI_SHIFT
155 sub r0, r0, #GIC_PRI_MASK
156 bx lr
157
158/*
159 * CPU例外ハンドラ呼出し前の割込みコントローラ操作
160 *
161 * irc_end_excで用いる情報（CPU例外発生前の割込み優先度マスク）を，スタッ
162 * クの先頭に保存する．
163 */
164 ATEXT
165 AALIGN(2)
166 AGLOBAL(irc_begin_exc)
167ALABEL(irc_begin_exc)
168 /*
169 * 割込み優先度マスクを保存する．
170 */
171 ldr r1, =GICC_PMR /* 現在の割込み優先度を取得 */
172 ldr r2, [r1]
173 str r2, [sp] /* irc_end_excで用いる情報を保存 */
174 bx lr
175
176/*
177 * CPU例外ハンドラ呼出し後の割込みコントローラ操作
178 */
179 ATEXT
180 AALIGN(2)
181 AGLOBAL(irc_end_exc)
182ALABEL(irc_end_exc)
183 /*
184 * 割込み優先度マスクを元に戻す．
185 */
186 ldr r2, [sp] /* irc_begin_excで保存した情報を復帰 */
187 ldr r1, =GICC_PMR /* 割込み優先度マスクを元に戻す */
188 str r2, [r1]
189 bx lr
Note: See TracBrowser for help on using the repository browser.